web-dev-qa-db-fra.com

Imprimer un numéro en langage d'assemblage?

mov al,10
add al,15

Comment imprimer la valeur de ' al '?

assemblyx86real-mode
20
Kristina Brooks

Avez-vous essayé int 21h service 2 ? DL est le caractère à imprimer.

mov dl,'A' ; print 'A'
mov ah,2
int 21h

Pour imprimer la valeur entière, vous devrez écrire une boucle pour décomposer l’entier en caractères individuels. Si vous acceptez d'imprimer la valeur en hexadécimal, c'est assez simple.

Si vous ne pouvez pas compter sur les services DOS, vous pourrez également utiliser le BIOS int 10h avec AL défini sur 0Eh ou 0Ah.

23
mrkj

Le langage d'assemblage n'a aucun moyen direct d'imprimer quoi que ce soit. Votre assembleur peut ou non venir avec une bibliothèque fournissant une telle installation, sinon vous devez l'écrire vous-même, et ce sera une fonction assez complexe. Vous devez également décider où imprimer, dans une fenêtre, sur une imprimante? En assembleur, rien de tout cela n'est fait pour vous.

7
anon

Valeur DOS 32 bits enregistrée dans EAX avec une sortie hexadécimale (pour 80386+)
(sous DOSBOX sous 64 bits)

.code
    mov ax,@DATA        ; get the address of the data segment
    mov ds,ax           ; store the address in the data segment register
;-----------------------
    mov eax,0FFFFFFFFh  ; 32 bit value (0 - FFFFFFFF) for example
;-----------------------
; convert the value in EAX to hexadecimal ASCIIs
;-----------------------
    mov di,OFFSET ASCII ; get the offset address
    mov cl,8            ; number of ASCII
P1: rol eax,4           ; 1 Nibble (start with highest byte)
    mov bl,al
    and bl,0Fh          ; only low-Nibble
    add bl,30h          ; convert to ASCII
    cmp bl,39h          ; above 9?
    jna short P2
    add bl,7            ; "A" to "F"
P2: mov [di],bl         ; store ASCII in buffer
    inc di              ; increase target address
    dec cl              ; decrease loop counter
    jnz P1              ; jump if cl is not equal 0 (zeroflag is not set)
;-----------------------
; Print string
;-----------------------
    mov dx,OFFSET ASCII ; DOS 1+ WRITE STRING TO STANDARD OUTPUT
    mov ah,9            ; DS:DX->'$'-terminated string
    int 21h             ; maybe redirected under DOS 2+ for output to file
                        ; (using pipe character">") or output to printer

  ; terminate program...

.data
ASCII DB "00000000",0Dh,0Ah,"$" ; buffer for ASCII string

La sortie de chaîne alternative directement vers le tampon vidéo sans utiliser d'interruption logicielle:

;-----------------------
; Print string
;-----------------------
    mov ax,0B800h       ; segment address of textmode video buffer
    mov es,ax           ; store address in extra segment register

    mov si,OFFSET ASCII ; get the offset address of the string

; using a fixed target address for example (screen page 0)
; Position`on screen = (Line_number*80*2) + (Row_number*2)

    mov di,(10*80*2)+(10*2)
    mov cl,8            ; number of ASCII
    cld                 ; clear direction flag

P3: lodsb  ; get the ASCII from the address in DS:SI + increase si
    stosb  ; write ASCII directly to the screen using ES:DI + increase di
    inc di ; step over attribut byte
    dec cl ; decrease counter
    jnz P3 ; repeat (print only 8 ASCII, not used bytes are: 0Dh,0Ah,"$")

; Hint: this directly output to the screen do not touch or move the cursor
; but feel free to modify..
3
Dirk Wolfgang Glomp
PRINT_SUM PROC NEAR
 CMP AL, 0
 JNE PRINT_AX
 Push AX
 MOV AL, '0'
 MOV AH, 0EH
 INT 10H
 POP AX
 RET 
    PRINT_AX:    
 PUSHA
 MOV AH, 0
 CMP AX, 0
 JE PN_DONE
 MOV DL, 10
 DIV DL    
 CALL PRINT_AX
 MOV AL, AH
 ADD AL, 30H
 MOV AH, 0EH
 INT 10H    
    PN_DONE:
 POPA  
 RET  
PRINT_SUM ENDP
1
ayat ziaee from iran

AH = 09 DS: DX = pointeur sur la chaîne se terminant par "$"

returns nothing


- outputs character string to STDOUT up to "$"
- backspace is treated as non-destructive
- if Ctrl-Break is detected, INT 23 is executed

ref: http://stanislavs.org/helppc/int_21-9.html

.data  

string db 2 dup(' ')

.code  
mov ax,@data  
mov ds,ax

mov al,10  
add al,15  
mov si,offset string+1  
mov bl,10  
div bl  
add ah,48  
mov [si],ah  
dec si  
div bl  
add ah,48  
mov [si],ah  

mov ah,9  
mov dx,string  
int 21h
0
user6849738

En supposant que vous écriviez un chargeur de démarrage ou une autre application ayant accès au BIOS, voici un aperçu de ce que vous pouvez faire:

  • Isoler le premier chiffre de l'octet hexadécimal
  • S'il est supérieur à 9 (c'est-à-dire 0x0A à 0x0F), soustrayez-en 10 (réduisez-le de 0 à 5) et ajoutez 'A' (0x41). 
  • Si elle est inférieure ou égale à 9 (c'est-à-dire 0x00 à 0x09), ajoutez-y un «0».
  • Répétez cette opération avec le prochain chiffre hexadécimal.

Voici ma mise en œuvre de ceci:

; Prints AL in hex.
printhexb:
    Push ax
    shr al, 0x04
    call print_nibble
    pop ax
    and al, 0x0F
    call print_nibble
    ret
print_nibble:
    cmp al, 0x09
    jg .letter
    add al, 0x30
    mov ah, 0x0E
    int 0x10
    ret
.letter:
    add al, 0x37
    mov ah, 0x0E
    int 0x10
    ret
0
Adrian Zhang

Vous aurez peut-être un peu de chance en appelant le MessageBoxA de l'API Win32, bien que Win16 prenne en charge cette méthode particulière appartient à une autre personne.

0
Rushyo