web-dev-qa-db-fra.com

compter des valeurs distinctes dans une feuille de calcul

J'ai une feuille de calcul Google avec une colonne qui ressemble à ceci:

City
----
London
Paris
London
Berlin
Rome
Paris

Je veux compter les apparences de chaque ville distincte (j'ai donc besoin du nom de la ville et du nombre d'apparences).

City   | Count
-------+------
London |  2
Paris  |  2
Berlin |  1
Rome   |  1

Comment je fais ça?

countgoogle-sheetsdistinct
66
Marius Bancila

Lien vers des exemples de travail

Solution 0

Ceci peut être accompagné de tableaux croisés dynamiques.

Pivot table Example - Count rows by value

Solution 1

Utilisez la formule unique pour obtenir toutes les valeurs distinctes. Ensuite, utilisez countif pour obtenir le nombre de chaque valeur. Voir le lien exemple de travail en haut pour voir exactement comment cela est implémenté.

Unique Values        Count
=UNIQUE(A3:A8)       =COUNTIF(A3:A8,B3)
                     =COUNTIF(A3:A8,B4)
                     ...

Solution 2

Si vous configurez vos données en tant que telles:

City    
----    
London   1
Paris    1
London   1
Berlin   1
Rome     1
Paris    1

Ensuite, ce qui suit produira le résultat souhaité.

=sort(transpose(query(A3:B8,"Select sum(B) pivot (A)")),2,FALSE)

Je suis sûr qu'il y a moyen de se débarrasser de la deuxième colonne car toutes les valeurs seront 1. Aucune solution idéale à mon avis.

via http://googledocsforlife.blogspot.com/2011/12/counting-unique-values-of-data-set.html

Autres liens éventuellement utiles

82
JSuar

=iferror(counta(unique(A1:A100))) compte le nombre de cellules uniques de A1 à A100

18
d-_-b

Vous pouvez utiliser la fonction query, donc si vos données étaient dans la colonne A où la première ligne était le titre de la colonne ...

=query(A2:A,"select A, count(A) where A != '' group by A order by count(A) desc label A 'City'", 0)

les rendements

City    count 
London  2
Paris   2
Berlin  1
Rome    1

Lien vers la feuille de travail Google.

https://docs.google.com/spreadsheets/d/1N5xw8-YP2GEPYOaRkX8iRA6DoeRXI86OkfuYxwXUCbc/edit#gid=

10
Mike Latch

Ce n'est pas exactement ce que l'utilisateur a demandé, mais un moyen facile de simplement compter les valeurs uniques:

Google a introduit une nouvelle fonction pour compter les valeurs uniques en une seule étape. Vous pouvez l'utiliser comme entrée pour d'autres formules:

=COUNTUNIQUE(A1:B10)

3
Fabricio PH

Cela fonctionne si vous voulez juste le nombre de valeurs uniques, par exemple. la gamme suivante

=counta(unique(B4:B21))
1
Paul

Ceci est similaire à la solution 1 de @JSuar ...

Supposons que vos données de ville d'origine correspondent à une plage nommée appelée dataCity. Dans une nouvelle feuille, entrez les informations suivantes:

    A                 | B
  ----------------------------------------------------------
1 | =UNIQUE(dataCity) | Count
2 |                   | =DCOUNTA(dataCity,"City",{"City";$A2})
3 |                   | [copy down the formula above]
4 |                   | ...
5 |                   | ...
0
dnlbrky