web-dev-qa-db-fra.com

Comment créer un nom de fonction dynamique en utilisant la macro Elixir?

Je veux créer dynamiquement un nom de fonction. J'ai écrit cette macro

defmacro generate_dynamic(name) do
  quote do 
    def add_(unquote(name)) do
    end
  end
end

Et je l'ai utilisé comme ceci:

defmodule AnotherModule do
  generate_dynamic :animal
end

Maintenant, je ne reçois que AnotherModule.add_ fonction définie, alors que j'attends AnotherModule.add_animal fonction.

elixir
34
shankardevy

Pour ce faire, vous pouvez ajouter :add_ au nom avant sans guillemets. En outre, les parenthèses après le nom de la méthode dans ce cas sont requises pour éviter les ambiguïtés. Cela devrait faire l'affaire:

defmacro generate_dynamic(name) do
  quote do 
    def unquote(:"add_#{name}")() do
      # ...
    end
  end
end
44
Patrick Oscity

Parfois, en tant que raccourci utile, vous pouvez obtenir le même résultat en ligne, sans écrire de macro à l'aide d'un fragment sans guillemets.

defmodule Hello do
  [:alice, :bob] |> Enum.each fn name ->
    def unquote(:"hello_#{name}")() do
      IO.inspect("Hello #{unquote(name)}")
    end
  end
end

Hello.hello_bob    # => "Hello bob"
Hello.hello_alice  # => "Hello alice"
21
Paweł Obrok

J'ai fait ce même genre de chose dans un Gist pour essayer d'imiter Ruby attr_accessor:

defmodule MacroExp do
  defmacro attr_accessor(atom) do
    getter = String.to_atom("get_#{atom}")
    setter = String.to_atom("set_#{atom}")
    quote do
      def unquote(getter)(data) do
        data |> Map.from_struct |> Map.get(unquote(atom))
      end
      def unquote(setter)(data, value) do
        data |> Map.put(unquote(atom), value)
      end
    end
  end

  defmacro attr_reader(atom) do
    getter = String.to_atom("get_#{atom}")
    quote do
      def unquote(getter)(data) do
        data |> Map.from_struct |> Map.get(unquote(atom))
      end
    end
  end
end


defmodule Calculation do
  import MacroExp
  defstruct first: nil, second: nil, operator: :plus

  attr_accessor :first   # defines set_first/2 and get_first/1
  attr_accessor :second  # defines set_second/2 and get_second/1
  attr_reader :operator  # defines set_operator/2 and get_operator/1

  def result(%Calculation{first: first, second: second, operator: :plus}) do
    first + second
  end
end

https://Gist.github.com/rcdilorenzo/77d7a29737de39f0cd84

6
Christian Di Lorenzo