web-dev-qa-db-fra.com

SUMPRODUCT vs SUMIFS

J'essaie de créer un guide Excel pour l'entreprise (nous sommes un petit organisme à but non lucratif et nous avons vraiment besoin d'une sorte de guide de référence). Cependant, je suis coincé en essayant d'expliquer les différences entre SUMPRODUCT et SUMIFS.

Ma compréhension est que SUMPRODUCT a été utilisé avant Excel 2007 comme un moyen d'avoir plusieurs critères sumif (entre autres). Maintenant que SUMIFS est disponible, y a-t-il une différence dans la capacité des deux formules?

J'ai regardé un peu autour de moi et j'ai trouvé que SUMIFS avait tendance à être plus rapide, mais c'était tout ... Tout aperçu et/ou matériel de lecture est apprécié!

Merci

excelexcel-formulasumifs
11
Kelley Hamrick

SUMPRODUCT peut être utilisé de manière plus flexible que SUMIFS car vous pouvez modifier les plages avec d'autres fonctions dans SUMPRODUCT, par exemple si vous avez une plage de dates dans A2:A100 comment pouvez-vous additionner les montants correspondants dans B2:B100 pour December dates (dans n'importe quelle année)?

Vous pouvez utiliser cette formule pour obtenir la réponse

=SUMPRODUCT((MONTH(A2:A100)=12)+0,B2:B100)

Vous ne pouvez pas le faire facilement avec SUMIFS, bien que si les dates sont toutes dans une année, vous pouvez simplement utiliser les points de début et de fin de la plage comme critère dans SUMIFS, par exemple pour décembre 2014 uniquement:

=SUMIFS(B2:B100,A2:A100,">="&DATE(2014,12,1),A2:A100,"<"&DATE(2015,1,1))

SUMPRODUCT peut également être utilisé pour référencer des données dans classeurs fermés , SUMIFS ne peut pas le faire - voir ici

http://support.Microsoft.com/kb/260415

... mais en général SUMIFS est beaucoup plus rapide, j'ai vu un chiffre 5x cité mais je ne l'ai pas vérifié.

Pour plusieurs utilisations intéressantes de SUMPRODUCT consultez cet article de MS Excel MVP Bob Philips

http://www.xldynamic.com/source/xld.SUMPRODUCT.html

9
barry houdini

SUMPRODUCT fonctionne comme des formules matricielles. Cela vous donne beaucoup plus de flexibilité que SUMIF. Voici un exemple où vous pouvez avoir un OR (+ dans summproduct)

=SUMPRODUCT((A1:A10="Marketing")*((B1:B10="North")+(B1:B10="South"))*(C1:C10))

Cela résumera tout ce qui a du marketing en A et au nord ou au sud en B.

Voici un exemple qui utilise une fonction sur une plage

=SUMPRODUCT((YEAR(A3:A7)=2014)*(B3:B7=1)*(C3:C7))

Cela résumera tout où l'année de la date dans le col A est 2014 et le col B est 1.

5
Dick Kusleika

SUMPRODUCT peut en fait additionner les produits de plusieurs tableaux, SUMIFS ne additionnera que les valeurs d'une seule plage.

par exemple. pour les données d'entrée

10    1
20    2
30    3

=SUMPRODUCT(A1:A3, B1:B3) => 10 * 1 + 20 * 2 + 30 * 3 = 140

4
Aprillion
  1. SUMIFS fonctionne généralement à % de la charge de calcul d'une formule SUMPRODUCT similaire.
  2. SUMIFS peut utiliser des références de colonne complètes (par exemple A: A au lieu de A2: A999) sans compromettre le décalage de calcul comme le fait SUMPRODUCT en calculant réellement le utilisé plage .
  3. SUMIFS saute joyeusement les valeurs de texte dans une colonne qui créerait une erreur avec SUMPRODUCT dans une opération mathématique.
  4. Alors que SUMPRODUCT fournit certaines fonctionnalités qui manquent à SUMIFS (la fonctionnalité OR mentionnée ci-dessus étant l'une des plus couramment requises), la plus récente SUMIFS est de loin la méthode préférée chaque fois qu'elle peut être utilisée.
4
user4039065