Essayer d'utiliser Google Sheets importHTML () pour importer un tableau. Il force le contenu à un format de date
J'essaie de mettre une table dans une feuille. La table contient des données qui ressemblent à ceci:
4-0-2
Ceci est gagnant-pertes-liens. Il vient comme une date. C'est la commande que j'utilise:
IMPORTHTML("http://www.sportsnet.ca/hockey/nhl/standings/", "table")
C'est le site:
http://www.sportsnet.ca/hockey/nhl/standings/
J'ai essayé de reformater les éléments de la feuille, mais le mal est fait.
Formules
Pour les colonnes 1-10
Sur la cellule A1, ajoutez la formule suivante:
=ARRAY_CONSTRAIN(IMPORTXML("http://www.sportsnet.ca/hockey/nhl/standings/",
"(//table)[1]//tr"),2000000,10)
Pour les colonnes 11-13
Sur les cellules K1 à M1, ajoutez la formule suivante sur chaque cellule
=ArrayFormula(
TEXT(IMPORTXML("http://www.sportsnet.ca/hockey/nhl/standings/",
"(//table)[1]/*/*/*["&COLUMN()&"]"),"d-m")&
IF(ISNUMBER(IMPORTXML("http://www.sportsnet.ca/hockey/nhl/standings/",
"(//table)[1]/*/*/*["&COLUMN()&"]")),
"-"&right(TEXT(IMPORTXML("http://www.sportsnet.ca/hockey/nhl/standings/",
"(//table)[1]/*/*/*["&COLUMN()&"]"),"y"),1),)
)
Pour la colonne 14
Sur la cellule N1, ajoutez la formule suivante
=IMPORTXML("http://www.sportsnet.ca/hockey/nhl/standings/",
"(//table)[1]/*/*/*["&COLUMN()&"]")
Explication
IMPORTHTML et IMPORTXML affectent le type de données avant d'ajouter les valeurs à la feuille de calcul.
Les formules présentées dans la section précédente peuvent être utilisées comme solution de contournement.
Voir également
Vous pouvez le faire dans une seule formule en utilisant array_constrain, query, index et regexreplace:
={ARRAY_CONSTRAIN(IMPORTHTML("http://www.sportsnet.ca/hockey/nhl/standings/", "table"),100,10),arrayformula(REGEXREPLACE(query(text(IMPORTHTML("http://www.sportsnet.ca/hockey/nhl/standings/", "table"),"M-D-YYYY"),"select Col11,Col12,Col13"),"(\d-\d-)(\d\d\d)(\d)","$1$3"))}
