web-dev-qa-db-fra.com

Sélectionner une ligne avec la valeur MAX par catégorie Power BI

Comment sélectionner une ligne avec une valeur maximale par catégorie dans M de Power BI. Supposons que nous ayons une table:

+----------+-------+------------+
| Category | Value |    Date    |
+----------+-------+------------+
| apples   |     1 | 2018-07-01 |
| apples   |     2 | 2018-07-02 |
| apples   |     3 | 2018-07-03 |
| bananas  |     7 | 2018-07-04 |
| bananas  |     8 | 2018-07-05 |
| bananas  |     9 | 2018-07-06 |
+----------+-------+------------+

Les résultats souhaités sont:

+----------+-------+------------+
| Category | Value |    Date    |
+----------+-------+------------+
| apples   |     3 | 2018-07-03 |
| bananas  |     9 | 2018-07-06 |
+----------+-------+------------+

Voici un tableau de départ pour PBI:

let
    Source = Table.FromRows(Json.Document(Binary.Decompress(Binary.FromText("i45WSiwoyEktVtJRMgRiIwNDC10Dc10DQ6VYHSQ5I2Q5I1Q5Y2Q5Y7BcUmIeEIIkzZElTdAkLZAlTdEkLZElzZRiYwE=", BinaryEncoding.Base64), Compression.Deflate)), let _t = ((type text) meta [Serialized.Text = true]) in type table [Category = _t, Value = _t, Date = _t]),
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Category", type text}, {"Value", Int64.Type}, {"Date", type date}})
in
    #"Changed Type"

Je me demande s’il est possible de parvenir aux résultats souhaités au cours des étapes suivantes dans une seule table, en ajoutant une colonne magique IsMax:

+----------+-------+------------+-------+
| Category | Value |    Date    | IsMax |
+----------+-------+------------+-------+
| apples   |     1 | 2018-07-01 |     0 |
| apples   |     2 | 2018-07-02 |     0 |
| apples   |     3 | 2018-07-03 |     1 |
| bananas  |     7 | 2018-07-04 |     0 |
| bananas  |     8 | 2018-07-05 |     0 |
| bananas  |     9 | 2018-07-06 |     1 |
+----------+-------+------------+-------+
powerbipowerquerym
1
Przemyslaw Remin

J'ai fini par obtenir MAX par catégorie à travers index. Idée décrite ici: https://stackoverflow.com/a/51498237/1903793

Mon moyen préféré est d'utiliser la transformation R:

library(dplyr)
output <- dataset %>% group_by(Category) %>% mutate(row_no_by_category = row_number(desc(Date)))

Le autre manière , fait complètement en PBI:

let
    Source = Table.FromRows(Json.Document(Binary.Decompress(Binary.FromText("i45WSiwoyEktVtJRMgRiIwNDC10Dc10DQ6VYHSQ5I2Q5I1Q5Y2Q5Y7BcUmIeEIIkzZElTdAkLZAlTdEkLZElzZRiYwE=", BinaryEncoding.Base64), Compression.Deflate)), let _t = ((type text) meta [Serialized.Text = true]) in type table [Category = _t, Value = _t, Date = _t]),
    #"Grouped rows" = Table.Group(Source, {"Category"}, {{"NiceTable", each Table.AddIndexColumn(Table.Sort(_,{{"Date", Order.Descending}} ), "Index",1,1), type table}} ),
    #"Expanded NiceTable" = Table.ExpandTableColumn(#"Grouped rows", "NiceTable", {"Value", "Date", "Index"}, {"Value", "Date", "Index"}),
    #"Filtered Rows" = Table.SelectRows(#"Expanded NiceTable", each ([Index] = 1))
in
    #"Filtered Rows"
0
Przemyslaw Remin

Faire un groupement de base par dans l'éditeur de requête de puissance (grouper par Category et prendre le maximum sur Value) vous donne le tableau suivant:

+----------+-------+
| Category | Value |
+----------+-------+
| apples   |     3 |
| bananas  |     9 |
+----------+-------+

Ajoutez une colonne personnalisée IsMax qui correspond simplement à la valeur 1 à cette table, puis fusionnez-la (jointure externe gauche) avec la table d'origine correspondant aux Category et Value. Enfin, développez la colonne IsMax pour obtenir votre table désirée, sauf avec null au lieu de 0. Vous pouvez remplacer les valeurs null si vous le souhaitez.

Voici le code M pour toutes ces étapes:

let
    Source = Table.FromRows(Json.Document(Binary.Decompress(Binary.FromText("i45WSiwoyEktVtJRMgRiIwNDC10Dc10DQ6VYHSQ5I2Q5I1Q5Y2Q5Y7BcUmIeEIIkzZElTdAkLZAlTdEkLZElzZRiYwE=", BinaryEncoding.Base64), Compression.Deflate)), let _t = ((type text) meta [Serialized.Text = true]) in type table [Category = _t, Value = _t, Date = _t]),
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Value", Int64.Type}, {"Date", type date}, {"Category", type text}}),
    #"Grouped Rows" = Table.Group(#"Changed Type", {"Category"}, {{"Value", each List.Max([Value]), Int64.Type}}),
    #"Added Custom" = Table.AddColumn(#"Grouped Rows", "IsMax", each 1, Int64.Type),
    #"Merged Queries" = Table.NestedJoin(#"Changed Type",{"Category", "Value"},#"Added Custom",{"Category", "Value"},"Added Custom",JoinKind.LeftOuter),
    #"Expanded Added Custom" = Table.ExpandTableColumn(#"Merged Queries", "Added Custom", {"IsMax"}, {"IsMax"})
in
    #"Expanded Added Custom"
3
Alexis Olson

Créez une colonne calculée:

IsMax =
VAR Max_Value =
    CALCULATE (
        MAX ( Table[Value] ),
        FILTER ( Table, Table[Category] = EARLIER ( Table[Category] ) )
    )
RETURN
    IF ( Table[Value] = Max_Value, 1, 0 )

Fonctionnement: Dans un premier temps, la fonction FILTER sélectionne tous les enregistrements de la table ayant la même catégorie que la ligne actuelle et trouve leur valeur maximale. Le résultat est enregistré dans une variable. Deuxièmement, IF compare la valeur de la ligne actuelle à la valeur maximale enregistrée. 

2
RADO