J'ai l'obligation de refléter quelques bases de données et d'utiliser également Cryptage de données transparentes (TDE) sur eux, car nos données doivent être cryptées alors que "au repos".
J'ai configuré tde sur le directeur et le miroir. Le problème que j'ai entre en jeu lorsque je confectionne la mise en miroir des deux bases de données. Depuis que j'utilise TDE, je ne connais pas de manière à configurer la mise en miroir via l'interface graphique, alors je suis obligé d'utiliser T-SQL pour faire le travail.
Vous trouverez ci-dessous le code que j'ai utilisé sur le serveur en miroir.
--Restore the full backup to the mirrored mdf and ldf
OPEN MASTER KEY DECRYPTION BY PASSWORD = '1Password'
RESTORE DATABASE TDE
FROM disk = '\\SERVERNAME\SQL_Stuff\Backup\TDE_FULL.bak'
WITH NORECOVERY,
REPLACE,
MOVE 'TDE' TO 'E:\TDE.mdf',
REPLACE,
MOVE 'TDE_log' TO 'G:\TDE.ldf'
CLOSE MASTER KEY
GO
--Restore the log backup to the mirrored db
OPEN MASTER KEY DECRYPTION BY PASSWORD = '1Password'
RESTORE LOG TDE
FROM DISK = '\\SERVERNAME\SQL_Stuff\Backup\TDE_LOG.trn'
WITH NORECOVERY;
CLOSE MASTER KEY
GO
--Drop/Create Mirroring endpoint on mirror
--DROP ENDPOINT TDE
CREATE ENDPOINT TDE
STATE = STARTED
AS TCP ( LISTENER_PORT = 7025 )
FOR DATABASE_MIRRORING (
ROLE = PARTNER
);
GO
--Check the endpoints for the mirror
USE MASTER
SELECT * FROM sys.database_mirroring_endpoints
GO
--Set the principal on the mirrored db
OPEN MASTER KEY DECRYPTION BY PASSWORD = '1Password'
ALTER DATABASE TDE SET PARTNER = 'TCP://PRINCIPAL.DOMAIN.local:7022'
GO
CLOSE MASTER KEY
GO
Vous trouverez ci-dessous le code que j'utilise sur le serveur principal.
----------------------Mirroring Section----------------------------------
--Full Backup of Principal
USE TDE
GO
BACKUP DATABASE TDE
TO DISK = '\\SERVERNAME\SQL_Stuff\Backup\TDE_FULL.bak'
WITH COMPRESSION,
NAME = 'Full Backup of TDE';
GO
---Log Backup of Principal
USE TDE
GO
BACKUP LOG TDE
TO DISK = '\\SERVERNAME\SQL_Stuff\Backup\TDE_LOG.trn'
WITH COMPRESSION,
NAME = 'Log backup of TDE'
GO
--Drop/Create Mirroring endpoint on principal
--DROP ENDPOINT TDE
CREATE ENDPOINT TDE
STATE = STARTED
AS TCP ( LISTENER_PORT = 7022 )
FOR DATABASE_MIRRORING (
ROLE = PARTNER
);
GO
--Check the endpoints for the princple
USE master
select * from sys.database_mirroring_endpoints
GO
--Set the mirror db on the principal db
OPEN MASTER KEY DECRYPTION BY PASSWORD = '1Password'
ALTER DATABASE TDE SET PARTNER = 'TCP://MIRROR.DOMAIN.local:7025'
CLOSE MASTER KEY
GO
Je configurais le point d'extrémité de miroir 1er, puis le point final principal. Je délivrais ensuite le ALTER DATABASE
on le miroir, puis sur le principal, où je reçois l'erreur résultante:
Msg 1416, Level 16, State 31, Line 2
Database "TDE" is not configured for database mirroring.
Je suis à perte de quoi faire à ce sujet. Le miroir est dans l'état "restauration", mais je suis certain que l'erreur parle de la DB principale.
Merci pour toute l'aide que vous pouvez nous apporter!
MISE À JOUR CODE POUR LE PRINCIPAL TDE:
--Create Master Key in Master Database
USE MASTER
GO
CREATE MASTER KEY ENCRYPTION BY PASSWORD = '1Password';
PRINT 'created master key'
go
--Backing up the master key file
USE master;
OPEN MASTER KEY DECRYPTION BY PASSWORD = '1Password';
BACKUP MASTER KEY TO FILE = '\\SERVERNAME\TDE_Master_Key.key' ENCRYPTION BY PASSWORD = '1Password';
GO
--Create Server Certificate in the Master Database encrypted with master key (created above) which would be used to create USER database encryption key.
USE Master
CREATE CERTIFICATE Cert_For_TDE WITH SUBJECT = 'Master_Cert_for_TDE', EXPIRY_DATE = '3500-Jan-01';
Go
--Backing up the server cert file
--USE master;
BACKUP CERTIFICATE Cert_For_TDE TO FILE = '\\SERVERNAME\TDE_Cert.cer'
WITH PRIVATE KEY ( FILE = '\\SERVERNAME\TDE_Cert_Key.key', ENCRYPTION BY PASSWORD = '1Password');
GO
--Create user database key
USE TDE
CREATE DATABASE ENCRYPTION KEY
WITH ALGORITHM = AES_256 ENCRYPTION BY SERVER CERTIFICATE Cert_For_TDE;
GO
--Enabling Transparent Database Encryption for the USER Database
USE master;
GO
ALTER DATABASE TDE SET ENCRYPTION ON
GO
Code sur miroir pour TDE:
--restore the backed up key to the mirror
use master
RESTORE MASTER KEY
FROM FILE = '\\SERVERNAME\TDE_Master_Key.key'
DECRYPTION BY PASSWORD = '1Password'
ENCRYPTION BY PASSWORD = '1Password';
GO
--restore the backed up cert to the mirror
USE Master;
OPEN MASTER KEY DECRYPTION BY PASSWORD = '1Password'
CREATE CERTIFICATE Cert_For_TDE
FROM FILE = '\\SERVERNAME\TDE_Cert.cer' WITH PRIVATE KEY ( FILE = '\\SERVERNAME\TDE_Cert_Key.key', DECRYPTION BY PASSWORD = '1Password');
GO
update2 sys.database_mirroringpoints réunis avec SYS.TCP_ENPOINTS sur le spectacle principal:
endpoint_id name principal_id state_desc role_desc connection_auth_desc certificate_id encryption_algorithm_desc port ip_address
65545 TDE 261 STARTED PARTNER NEGOTIATE 0 RC4 7022 NULL
sYS.DATABASE_MIRRORINGKPOINTS JOINT MOINS DE SYS.TCP_ENDPOINTS SUR MIROIR SHOW:
endpoint_id name principal_id state_desc role_desc connection_auth_desc certificate_id encryption_algorithm_desc port ip_address
65537 TDE 261 STARTED PARTNER NEGOTIATE 0 RC4 7025 NULL
Trouvé a Site Web avec un commentaire sur celui-ci.
J'ai ajouté le code à juste après où je restaure la clé et le cert
--Mumbojumbo to get mirroring to work
OPEN MASTER KEY DECRYPTION BY PASSWORD = '1Password'
ALTER MASTER KEY ADD ENCRYPTION BY SERVICE MASTER KEY
GO
Cela fonctionne comme un charme, il est peu de sens que je devrais crypter la clé principale que j'ai restaurée avec la clé de service du nouveau serveur. J'imagine.
haussement d'épaules