web-dev-qa-db-fra.com

Contrainte de clé étrangère SQL DROP TABLE

Si je veux supprimer toutes les tables de ma base de données de cette façon, est-ce que cela va prendre en charge la contrainte de clé étrangère? Si non, comment puis-je m'en occuper en premier?

GO
IF OBJECT_ID('dbo.[Course]','U') IS NOT NULL
    DROP TABLE dbo.[Course]
GO
IF OBJECT_ID('dbo.[Student]','U') IS NOT NULL
    DROP TABLE dbo.[Student]
sql-serverforeign-keysconstraintsdatabase-tabledrop-table
124
user188229

Non, cela ne lâchera pas votre table s'il y a effectivement des clés étrangères qui la référencent.

Pour obtenir toutes les relations de clé étrangère référençant votre table, vous pouvez utiliser ce SQL (si vous êtes sur SQL Server 2005 et versions supérieures):

SELECT * 
FROM sys.foreign_keys
WHERE referenced_object_id = object_id('Student')

et s'il y en a, avec cette instruction ici, vous pouvez créer des instructions SQL pour supprimer ces relations FK:

SELECT 
    'ALTER TABLE [' +  OBJECT_SCHEMA_NAME(parent_object_id) +
    '].[' + OBJECT_NAME(parent_object_id) + 
    '] DROP CONSTRAINT [' + name + ']'
FROM sys.foreign_keys
WHERE referenced_object_id = object_id('Student')
285
marc_s

Dans SQL Server Management Studio 2008 (R2) et versions ultérieures, vous pouvez cliquer avec le bouton droit de la souris sur la souris. 

DB -> Tâches -> Générer des scripts

  • Sélectionnez les tables que vous souhaitez supprimer.

  • Sélectionnez "Enregistrer dans une nouvelle fenêtre de requête".

  • Cliquez sur le bouton Avancé.

  • Définissez Script DROP et CREATE sur Script DROP.

  • Définissez les clés étrangères de script sur True.

  • Cliquez sur OK.

  • Cliquez sur Suivant -> Suivant -> Terminer.

  • Affichez le script, puis exécutez.

30
Riaan

Si vous supprimez d'abord la table "enfant", la clé étrangère sera également supprimée. Si vous essayez d'abord de supprimer la table "parent", vous obtiendrez un "Impossible de supprimer l'objet" a "car il est référencé par une contrainte FOREIGN KEY" Erreur.

16
Philip Kelley

Voici un autre moyen de supprimer toutes les tables correctement, en utilisant la procédure sp_MSdropconstraints. Le code le plus court auquel je pouvais penser:

exec sp_MSforeachtable "declare @name nvarchar(max); set @name = parsename('?', 1); exec sp_MSdropconstraints @name";
exec sp_MSforeachtable "drop table ?";
10
Krait

Version légèrement plus générique de ce que @mark_s a posté, cela m'a aidé

SELECT 
'ALTER TABLE ' +  OBJECT_SCHEMA_NAME(k.parent_object_id) +
'.[' + OBJECT_NAME(k.parent_object_id) + 
'] DROP CONSTRAINT ' + k.name
FROM sys.foreign_keys k
WHERE referenced_object_id = object_id('your table')

il suffit de brancher le nom de votre table et d’exécuter le résultat.

2
Stas Svishov

S'il s'agit de SQL Server, vous devez supprimer la contrainte avant de pouvoir supprimer la table.

2
Shiraz Bhaiji

Voici un autre moyen de supprimer toutes les contraintes suivies par les tables elles-mêmes, en utilisant une astuce de concaténation impliquant FOR XML PATH('') qui permet de fusionner plusieurs lignes en entrée en une seule ligne en sortie. Devrait fonctionner sur quoi que ce soit SQL 2005 et versions ultérieures.

J'ai laissé les commandes EXECUTE commentées pour des raisons de sécurité.

DECLARE @SQL NVARCHAR(max)
;WITH fkeys AS (
    SELECT quotename(s.name) + '.' + quotename(o.name) tablename, quotename(fk.name) constraintname 
    FROM sys.foreign_keys fk
    JOIN sys.objects o ON fk.parent_object_id = o.object_id
    JOIN sys.schemas s ON o.schema_id = s.schema_id
)
SELECT @SQL = STUFF((SELECT '; ALTER TABLE ' + tablename + ' DROP CONSTRAINT ' + constraintname
FROM fkeys
FOR XML PATH('')),1,2,'')

-- EXECUTE(@sql)

SELECT @SQL = STUFF((SELECT '; DROP TABLE ' + quotename(TABLE_SCHEMA) + '.' + quotename(TABLE_NAME) 
FROM INFORMATION_SCHEMA.TABLES 
FOR XML PATH('')),1,2,'')

-- EXECUTE(@sql)
1
Warren Rumak

Voici un script complet pour implémenter une solution:

create Procedure [dev].DeleteTablesFromSchema
(
    @schemaName varchar(500)
)
As 
begin
    declare @constraintSchemaName nvarchar(128), @constraintTableName nvarchar(128),  @constraintName nvarchar(128)
    declare @sql nvarchar(max)
    -- delete FK first
    declare cur1 cursor for
    select distinct 
    CASE WHEN t2.[object_id] is NOT NULL  THEN  s2.name ELSE s.name END as SchemaName,
    CASE WHEN t2.[object_id] is NOT NULL  THEN  t2.name ELSE t.name END as TableName,
    CASE WHEN t2.[object_id] is NOT NULL  THEN  OBJECT_NAME(d2.constraint_object_id) ELSE OBJECT_NAME(d.constraint_object_id) END as ConstraintName
    from sys.objects t 
        inner join sys.schemas s 
            on t.[schema_id] = s.[schema_id]
        left join sys.foreign_key_columns d 
            on  d.parent_object_id = t.[object_id]
        left join sys.foreign_key_columns d2 
            on  d2.referenced_object_id = t.[object_id]
        inner join sys.objects t2 
            on  d2.parent_object_id = t2.[object_id]
        inner join sys.schemas s2 
            on  t2.[schema_id] = s2.[schema_id]
    WHERE t.[type]='U' 
        AND t2.[type]='U'
        AND t.is_ms_shipped = 0 
        AND t2.is_ms_shipped = 0 
        AND s.Name=@schemaName
    open cur1
    fetch next from cur1 into @constraintSchemaName, @constraintTableName, @constraintName
    while @@fetch_status = 0
    BEGIN
        set @sql ='ALTER TABLE ' + @constraintSchemaName + '.' + @constraintTableName+' DROP CONSTRAINT '+@constraintName+';'
        exec(@sql)
        fetch next from cur1 into @constraintSchemaName, @constraintTableName, @constraintName
    END
    close cur1
    deallocate cur1

    DECLARE @tableName nvarchar(128)
    declare cur2 cursor for
    select s.Name, p.Name
    from sys.objects p
        INNER JOIN sys.schemas s ON p.[schema_id] = s.[schema_id]
    WHERE p.[type]='U' and is_ms_shipped = 0 
    AND s.Name=@schemaName
    ORDER BY s.Name, p.Name
    open cur2

    fetch next from cur2 into @schemaName,@tableName
    while @@fetch_status = 0
    begin
        set @sql ='DROP TABLE ' + @schemaName + '.' + @tableName
        exec(@sql)
        fetch next from cur2 into @schemaName,@tableName
    end

    close cur2
    deallocate cur2

end
go
1
Roman Pokrovskij

Si je veux supprimer toutes les tables de ma base de données

Il est alors beaucoup plus facile de supprimer toute la base de données:

DROP DATABASE WorkerPensions
0
Andomar
Removing Referenced FOREIGN KEY Constraints
Assuming there is a parent and child table Relationship in SQL Server:

--First find the name of the Foreign Key Constraint:
  SELECT * 
  FROM sys.foreign_keys
  WHERE referenced_object_id = object_id('States')

--Then Find foreign keys referencing to dbo.Parent(States) table:
   SELECT name AS 'Foreign Key Constraint Name', 
           OBJECT_SCHEMA_NAME(parent_object_id) + '.' + OBJECT_NAME(parent_object_id) AS 'Child Table'
   FROM sys.foreign_keys 
   WHERE OBJECT_SCHEMA_NAME(referenced_object_id) = 'dbo' AND 
              OBJECT_NAME(referenced_object_id) = 'dbo.State'

 -- Drop the foreign key constraint by its name 
   ALTER TABLE dbo.cities DROP CONSTRAINT FK__cities__state__6442E2C9;

 -- You can also use the following T-SQL script to automatically find 
 --and drop all foreign key constraints referencing to the specified parent 
 -- table:

 BEGIN

DECLARE @stmt VARCHAR(300);

-- Cursor to generate ALTER TABLE DROP CONSTRAINT statements  
 DECLARE cur CURSOR FOR
 SELECT 'ALTER TABLE ' + OBJECT_SCHEMA_NAME(parent_object_id) + '.' + 
 OBJECT_NAME(parent_object_id) +
                ' DROP CONSTRAINT ' + name
 FROM sys.foreign_keys 
 WHERE OBJECT_SCHEMA_NAME(referenced_object_id) = 'dbo' AND 
            OBJECT_NAME(referenced_object_id) = 'states';

 OPEN cur;
 FETCH cur INTO @stmt;

 -- Drop each found foreign key constraint 
  WHILE @@FETCH_STATUS = 0
  BEGIN
    EXEC (@stmt);
    FETCH cur INTO @stmt;
  END

  CLOSE cur;
  DEALLOCATE cur;

  END
  GO

--Now you can drop the parent table:

 DROP TABLE states;
--# Command(s) completed successfully.
0
CodeTzu

À l'aide de SQL Server Manager, vous pouvez supprimer les contraintes de clé étrangère de l'interface utilisateur. Si vous souhaitez supprimer la table Diary mais que la table utilisateur possède une clé étrangère DiaryId pointant vers la table Diary, vous pouvez développer (à l'aide du symbole plus) la table User, puis la section Foreign Keys. Cliquez avec le bouton droit sur la clé étrangère qui pointe vers la table des journaux, puis sélectionnez Delete. Vous pouvez ensuite développer la section Columns, cliquer avec le bouton droit de la souris et supprimer également la colonne DiaryId. Ensuite, vous pouvez simplement lancer:

drop table Diary

Je sais que votre question porte sur la suppression de toutes les tables. Cela pourrait donc ne pas être utile dans ce cas. Toutefois, si vous souhaitez simplement supprimer quelques tableaux, cela est utile, je pense (le titre ne mentionne pas explicitement la suppression de tous les tableaux).

0
Hazza