web-dev-qa-db-fra.com

Si la condition EXISTS ne fonctionne pas avec PLSQL

J'essaie d'imprimer le texte lorsque la condition est vraie. Le code de sélection fonctionne parfaitement. Il montre la valeur 403 quand je lance seulement le code de sélection. Mais je dois imprimer du texte quand la condition existe. Quel est le problème avec le code suivant.

BEGIN
IF EXISTS(
SELECT CE.S_REGNO FROM
COURSEOFFERING CO
JOIN CO_ENROLMENT CE
  ON CE.CO_ID = CO.CO_ID
WHERE CE.S_REGNO=403 AND CE.COE_COMPLETIONSTATUS = 'C' AND CO.C_ID = 803
)
THEN
    DBMS_OUTPUT.put_line('YES YOU CAN');
END;

Voici le rapport d'erreur:

Error report:
ORA-06550: line 5, column 1:
PLS-00103: Encountered the symbol "JOIN" when expecting one of the following:

   ) , with group having intersect minus start union where
   connect
06550. 00000 -  "line %s, column %s:\n%s"
*Cause:    Usually a PL/SQL compilation error.
*Action:
sqloracleif-statementplsql
30
nirmalgyanwali

IF EXISTS() est sémantiquement incorrect. La condition EXISTS ne peut être utilisée que dans une instruction SQL. Vous pouvez donc réécrire votre bloc pl/sql comme suit:

declare
  l_exst number(1);
begin
  select case 
           when exists(select ce.s_regno 
                         from courseoffering co
                         join co_enrolment ce
                           on ce.co_id = co.co_id
                        where ce.s_regno=403 
                          and ce.coe_completionstatus = 'C' 
                          and ce.c_id = 803
                          and rownum = 1
                        )
           then 1
           else 0
         end  into l_exst
  from dual;

  if l_exst = 1 
  then
    DBMS_OUTPUT.put_line('YES YOU CAN');
  else
    DBMS_OUTPUT.put_line('YOU CANNOT'); 
  end if;
end;

Ou vous pouvez simplement utiliser la fonction count pour déterminer le nombre de lignes renvoyées par la requête et rownum=1 prédicat - il suffit de savoir s’il existe un enregistrement:

declare
  l_exst number;
begin
   select count(*) 
     into l_exst
     from courseoffering co
          join co_enrolment ce
            on ce.co_id = co.co_id
    where ce.s_regno=403 
      and ce.coe_completionstatus = 'C' 
      and ce.c_id = 803
      and rownum = 1;

  if l_exst = 0
  then
    DBMS_OUTPUT.put_line('YOU CANNOT');
  else
    DBMS_OUTPUT.put_line('YES YOU CAN');
  end if;
end;
50
Nick Krasnov

Malheureusement, PL/SQL n'a pas IF EXISTS opérateur comme SQL Server. Mais vous pouvez faire quelque chose comme ça:

begin
  for x in ( select count(*) cnt
               from dual 
              where exists (
                select 1 from courseoffering co
                  join co_enrolment ce on ce.co_id = co.co_id
                 where ce.s_regno = 403 
                   and ce.coe_completionstatus = 'C' 
                   and co.c_id = 803 ) )
  loop
        if ( x.cnt = 1 ) 
        then
           dbms_output.put_line('exists');
        else 
           dbms_output.put_line('does not exist');
        end if;
  end loop;
end;
/
6
HiltoN