Enregistrer les pièces jointes dans un dossier et les renommer

Question

J'essaie d'obtenir une macro VBA dans Outlook qui enregistre la pièce jointe d'un courrier électronique dans un dossier spécifique et ajoute la date receive au nom du fichier. 

Ma recherche sur Google m'a amené jusque-là:

Public Sub saveAttachtoDisk (itm As Outlook.MailItem) 
    Dim objAtt As Outlook.Attachment 
    Dim saveFolder As String
    Dim dateFormat As String
    saveFolder = "C:\Temp\"
    dateFormat = Format(Now, "yyyy-mm-dd H-mm")

    For Each objAtt In itm.Attachments
        objAtt.SaveAsFile saveFolder & "\" & dateFormat & objAtt.DisplayName
        Set objAtt = Nothing
    Next 
End Sub

La première chose évidente est qu’il applique l’heure actuelle au nom de fichier au lieu de l’heure reçue, mais je ne peux apparemment pas le changer. Ma théorie est que Outlook.Attachment n'a pas de ReceivedTime et que le courrier électronique lui-même doit être référencé.

Deuxièmement, cela ne semble pas fonctionner du tout, ha! Cela a fonctionné le premier jour où j'ai commencé à bricoler mais après cela, il a cessé de sauvegarder des fichiers.

Answer 1

Ceci est mon script Enregistrer les pièces jointes. Vous sélectionnez tous les messages à partir desquels vous souhaitez enregistrer les pièces jointes. Une copie est alors sauvegardée. Il ajoute également du texte au corps du message indiquant l'endroit où la pièce jointe est enregistrée. Vous pouvez facilement changer le nom du dossier pour inclure la date, mais vous devez vous assurer que le dossier existe avant de commencer à enregistrer des fichiers.

Public Sub SaveAttachments()
Dim objOL As Outlook.Application
Dim objMsg As Outlook.MailItem 'Object
Dim objAttachments As Outlook.Attachments
Dim objSelection As Outlook.Selection
Dim i As Long
Dim lngCount As Long
Dim strFile As String
Dim strFolderpath As String
Dim strDeletedFiles As String

' Get the path to your My Documents folder
strFolderpath = CreateObject("WScript.Shell").SpecialFolders(16)
On Error Resume Next

' Instantiate an Outlook Application object.
Set objOL = CreateObject("Outlook.Application")

' Get the collection of selected objects.
Set objSelection = objOL.ActiveExplorer.Selection

' Set the Attachment folder.
strFolderpath = strFolderpath & "\Attachments\"

' Check each selected item for attachments. If attachments exist,
' save them to the strFolderPath folder and strip them from the item.
For Each objMsg In objSelection

    ' This code only strips attachments from mail items.
    ' If objMsg.class=olMail Then
    ' Get the Attachments collection of the item.
    Set objAttachments = objMsg.Attachments
    lngCount = objAttachments.Count
    strDeletedFiles = ""

    If lngCount > 0 Then

        ' We need to use a count down loop for removing items
        ' from a collection. Otherwise, the loop counter gets
        ' confused and only every other item is removed.

        For i = lngCount To 1 Step -1

            ' Save attachment before deleting from item.
            ' Get the file name.
            strFile = objAttachments.Item(i).FileName

            ' Combine with the path to the Temp folder.
            strFile = strFolderpath & strFile

            ' Save the attachment as a file.
            objAttachments.Item(i).SaveAsFile strFile

            ' Delete the attachment.
            objAttachments.Item(i).Delete

            'write the save as path to a string to add to the message
            'check for html and use html tags in link
            If objMsg.BodyFormat <> olFormatHTML Then
                strDeletedFiles = strDeletedFiles & vbCrLf & "<file://" & strFile & ">"
            Else
                strDeletedFiles = strDeletedFiles & "<br>" & "<a href='file://" & _
                strFile & "'>" & strFile & "</a>"
            End If

            'Use the MsgBox command to troubleshoot. Remove it from the final code.
            'MsgBox strDeletedFiles

        Next i

        ' Adds the filename string to the message body and save it
        ' Check for HTML body
        If objMsg.BodyFormat <> olFormatHTML Then
            objMsg.Body = vbCrLf & "The file(s) were saved to " & strDeletedFiles & vbCrLf & objMsg.Body
        Else
            objMsg.HTMLBody = "<p>" & "The file(s) were saved to " & strDeletedFiles & "</p>" & objMsg.HTMLBody
        End If
        objMsg.Save
    End If
Next

ExitSub:

Set objAttachments = Nothing
Set objMsg = Nothing
Set objSelection = Nothing
Set objOL = Nothing
End Sub

Answer 2

Voir la propriété ReceivedTime

http://msdn.Microsoft.com/en-us/library/office/aa171873(v=office.11).aspx

Vous avez ajouté un autre \ à la fin de C:\Temp\ dans la ligne SaveAs File. Pourrait être un problème. Faites un test avant d'ajouter un séparateur de chemin.

dateFormat = Format(itm.ReceivedTime, "yyyy-mm-dd H-mm")  
saveFolder = "C:\Temp"

Vous n'avez pas défini objAtt, vous n'avez donc pas besoin de "Set objAtt = Nothing". S'il y en avait, ce serait juste avant End Sub pas dans la boucle.

---

Public Sub saveAttachtoDisk (itm As Outlook.MailItem) 
    Dim objAtt As Outlook.Attachment 
    Dim saveFolder As String Dim dateFormat
    dateFormat = Format(itm.ReceivedTime, "yyyy-mm-dd H-mm")  saveFolder = "C:\Temp"
    For Each objAtt In itm.Attachments
        objAtt.SaveAsFile saveFolder & "\" & dateFormat & objAtt.DisplayName
    Next
End Sub

Re: Cela a fonctionné le premier jour où j'ai commencé à bricoler, mais après cela, il a cessé de sauvegarder des fichiers.

Cela est généralement dû aux paramètres de sécurité. Il s'agit d'un "piège" défini pour les nouveaux utilisateurs qui autorisent les macros puis l'enlève. http://www.slipstick.com/Outlook-developer/how-to-use-outlooks-vba-editor/

Answer 3

Votre question a 2 tâches à exécuter. Commencez par extraire les pièces jointes d'un courrier électronique dans un dossier, puis enregistrez ou renommez-le sous un nom spécifique. 

Si votre recherche peut être divisée en 2 recherches, vous obtiendrez plus de résultats. Je pourrais faire référence à une page qui explique comment enregistrer la pièce jointe dans un dossier système < Lien vers la page permettant d’enregistrer les pièces jointes dans un dossier >.

S'il vous plaît publier une page ou un code si vous avez trouvé pour enregistrer la pièce jointe avec un nom spécifique.

Answer 4

Ajout d'un code simple pour enregistrer avec un horodatage lisible.

Utilisez sync2pst pour synchroniser toutes vos données dans Outlook avec tous vos appareils, procédez comme suit:

1. il vous suffit d'acheter une licence: enregistrez votre fichier pst sur un ordinateur (appelons ce serveur 'serveur') sur votre réseau.
2. créez des tâches planifiées qui synchroniseront le fichier pst sur votre 'serveur' avec tous les fichiers pst de tous vos appareils, quel que soit l'appareil ayant d'abord téléchargé les courriels (vous avez besoin de quelques connaissances en programmation pour contourner les fichiers pst ouverts au moment de la synchronisation) .
3. sauvegardez toutes vos pièces jointes dans le même dossier skydrive qui se trouve au même endroit sur tous vos appareils (par exemple, e:\skydrive\attachments).
4. Utilisez le code ci-dessous sur tous vos appareils pour enregistrer les pièces jointes (modifiez le chemin comme indiqué ci-dessus)

5. Utilisez UN SEUL fichier PST pour tous vos comptes, créez des dossiers, des sous-dossiers, etc.

6. sous VBA: voir 'Microsoft scripting runtime' extra/references ... '

7. voici le code

Private Sub Application_NewMail()
SaveAttachments
End Sub

Public Sub SaveAttachments()
Dim objOL As Outlook.Application
Dim objMsg As Outlook.MailItem 'Object
Dim objAttachments As Outlook.Attachments
Dim objSelection As Outlook.Selection
Dim i As Long
Dim lngCount As Long
Dim strFile As String
Dim strFolderpath As String
Dim strDeletedFiles As String
Dim fs As FileSystemObject

' Get the path to your My Documents folder
strFolderpath = CreateObject("WScript.Shell").SpecialFolders(16)
On Error Resume Next

' Instantiate an Outlook Application object.
Set objOL = CreateObject("Outlook.Application")

' Get the collection of selected objects.
Set objSelection = objOL.ActiveExplorer.Selection

' Set the Attachment folder.
strFolderpath = "F:\SkyDrive\Attachments\"

' Check each selected item for attachments. If attachments exist,
' save them to the strFolderPath folder and strip them from the item.
For Each objMsg In objSelection

    ' This code only strips attachments from mail items.
    ' If objMsg.class=olMail Then
    ' Get the Attachments collection of the item.
    Set objAttachments = objMsg.Attachments
    lngCount = objAttachments.Count
    strDeletedFiles = ""

    If lngCount > 0 Then

        ' We need to use a count down loop for removing items
        ' from a collection. Otherwise, the loop counter gets
        ' confused and only every other item is removed.
        Set fs = New FileSystemObject

        For i = lngCount To 1 Step -1

            ' Save attachment before deleting from item.
            ' Get the file name.
            strFile = Left(objAttachments.Item(i).FileName, Len(objAttachments.Item(i).FileName) - 4) + "_" + Right("00" + Trim(Str$(Day(Now))), 2) + "_" + Right("00" + Trim(Str$(Month(Now))), 2) + "_" + Right("0000" + Trim(Str$(Year(Now))), 4) + "_" + Right("00" + Trim(Str$(Hour(Now))), 2) + "_" + Right("00" + Trim(Str$(Minute(Now))), 2) + "_" + Right("00" + Trim(Str$(Second(Now))), 2) + Right((objAttachments.Item(i).FileName), 4)

            ' Combine with the path to the Temp folder.
            strFile = strFolderpath & strFile

            ' Save the attachment as a file.
            objAttachments.Item(i).SaveAsFile strFile

            ' Delete the attachment.
            objAttachments.Item(i).Delete

            'write the save as path to a string to add to the message
            'check for html and use html tags in link
            If objMsg.BodyFormat <> olFormatHTML Then
                strDeletedFiles = strDeletedFiles & vbCrLf & "<file://" & strFile & ">"
            Else
                strDeletedFiles = strDeletedFiles & "<br>" & "<a href='file://" & _
                strFile & "'>" & strFile & "</a>"
            End If

            'Use the MsgBox command to troubleshoot. Remove it from the final code.
            'MsgBox strDeletedFiles

        Next i

        ' Adds the filename string to the message body and save it
        ' Check for HTML body
        If objMsg.BodyFormat <> olFormatHTML Then
            objMsg.Body = vbCrLf & "The file(s) were saved to " & strDeletedFiles & vbCrLf & objMsg.Body
        Else
            objMsg.HTMLBody = "<p>" & "The file(s) were saved to " & strDeletedFiles & "</p>" & objMsg.HTMLBody
        End If

        objMsg.Save
    End If
Next

ExitSub:

Set objAttachments = Nothing
Set objMsg = Nothing
Set objSelection = Nothing
Set objOL = Nothing
End Sub

Answer 5

Public Sub Extract_Outlook_Email_Attachments()

Dim OutlookOpened As Boolean
Dim outApp As Outlook.Application
Dim outNs As Outlook.Namespace
Dim outFolder As Outlook.MAPIFolder
Dim outAttachment As Outlook.Attachment
Dim outItem As Object
Dim saveFolder As String
Dim outMailItem As Outlook.MailItem
Dim inputDate As String, subjectFilter As String


saveFolder = "Y:\Wingman" ' THIS IS WHERE YOU WANT TO SAVE THE ATTACHMENT TO

If Right(saveFolder, 1) <> "\" Then saveFolder = saveFolder & "\"

subjectFilter = ("Daily Operations Custom All Req Statuses Report") ' THIS IS WHERE YOU PLACE THE EMAIL SUBJECT FOR THE CODE TO FIND

OutlookOpened = False
On Error Resume Next
Set outApp = GetObject(, "Outlook.Application")
If Err.Number <> 0 Then
    Set outApp = New Outlook.Application
    OutlookOpened = True
End If
On Error GoTo 0

If outApp Is Nothing Then
    MsgBox "Cannot start Outlook.", vbExclamation
    Exit Sub
End If

Set outNs = outApp.GetNamespace("MAPI")
Set outFolder = outNs.GetDefaultFolder(olFolderInbox)

If Not outFolder Is Nothing Then
    For Each outItem In outFolder.Items
        If outItem.Class = Outlook.OlObjectClass.olMail Then
            Set outMailItem = outItem
                If InStr(1, outMailItem.Subject, "subjectFilter") > 0 Then
                    For Each outAttachment In outMailItem.Attachments
                    outAttachment.SaveAsFile saveFolder & outAttachment.filename

                    Set outAttachment = Nothing

                    Next
                End If
        End If
    Next
End If

If OutlookOpened Then outApp.Quit

Set outApp = Nothing

End Sub

Answer 6

En fait, je l'avais résolu peu de temps après la publication, mais je n'avais pas posté ma solution. Honnêtement, je ne m'en souviens pas. Mais j'ai dû revoir la tâche quand on m'a confié un nouveau projet qui faisait face au même défi.

J'ai utilisé la propriété ReceivedTime de Outlook.MailItem pour obtenir l'horodatage. J'ai pu l'utiliser comme identificateur unique pour chaque fichier afin d'éviter tout remplacement mutuel.

Public Sub saveAttachtoDisk(itm As Outlook.MailItem)
    Dim objAtt As Outlook.Attachment
    Dim saveFolder As String
        saveFolder = "C:\PathToDirectory\"
    Dim dateFormat As String
        dateFormat = Format(itm.ReceivedTime, "yyyy-mm-dd Hmm ")
    For Each objAtt In itm.Attachments
        objAtt.SaveAsFile saveFolder & "\" & dateFormat & objAtt.DisplayName
    Next
End Sub

Merci beaucoup pour les autres solutions, beaucoup d'entre elles vont au-delà d'un dépassement :)