Comment forcer Windows à vérifier les mises à jour?
Après une nouvelle installation de Windows - XP ou 7 - comment "forcer" les mises à jour de Windows?
Je ne veux pas avoir de "vieilles" mises à jour Windows après une semaine, est-ce que cela pourrait être fait en "une étape"? Existe-t-il des commandes "magiques" qui obligent Windows à rechercher les mises à jour et, le cas échéant, à les installer?
Vous pouvez rechercher et installer automatiquement les mises à jour à l'aide d'un script. Cela fonctionnera sous XP ou Windows 7.
Il existe un certain nombre de scripts disponibles pour le téléchargement, voici le mien :
' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain. It may be freely
' used, modified, and distributed. However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
' 0 = scripting failure
' 1 = error obtaining or installing updates
' 2 = installation successful, no further updates to install
' 3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'
Set updateSession = CreateObject("Microsoft.Update.Session")
Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()
Do
WScript.Echo
WScript.Echo "Searching for approved updates ..."
WScript.Echo
Set updateSearch = updateSearcher.Search("IsInstalled=0")
If updateSearch.ResultCode <> 2 Then
WScript.Echo "Search failed with result code", updateSearch.ResultCode
WScript.Quit 1
End If
If updateSearch.Updates.Count = 0 Then
WScript.Echo "There are no updates to install."
WScript.Quit 2
End If
Set updateList = updateSearch.Updates
For I = 0 to updateSearch.Updates.Count - 1
Set update = updateList.Item(I)
WScript.Echo "Update found:", update.Title
Next
WScript.Echo
updateDownloader.Updates = updateList
updateDownloader.Priority = 3
Set downloadResult = updateDownloader.Download()
If downloadResult.ResultCode <> 2 Then
WScript.Echo "Download failed with result code", downloadResult.ResultCode
WScript.Echo
WScript.Quit 1
End If
WScript.Echo "Download complete. Installing updates ..."
WScript.Echo
updateInstaller.Updates = updateList
Set installationResult = updateInstaller.Install()
If installationResult.ResultCode <> 2 Then
WScript.Echo "Installation failed with result code", installationResult.ResultCode
For I = 0 to updateList.Count - 1
Set updateInstallationResult = installationResult.GetUpdateResult(I)
WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode
Next
WScript.Quit 1
End If
If installationResult.RebootRequired Then
WScript.Echo "The system must be rebooted to complete installation."
WScript.Quit 3
End If
WScript.Echo "Installation complete."
Loop
Vous exécutez ceci à partir de la ligne de commande comme ceci:
cscript wsusupdate.vbs
Mon script n'est que très peu fonctionnel mais peut quand même être utile. Il existe d'autres scripts de ce type avec de nombreuses fonctionnalités supplémentaires. Essayez une recherche sur Google.
Au-delà de la manière habituelle d’utiliser Windows Update, vous pouvez forcer une vérification à partir d’une ligne de commande.
Ouvrez une commande administrateur Invite et lancez:
C:\> %windir%\system32\wuauclt.exe /detectnow
Wuauclt.exe est le client AutoUpdate de Windows Update et permet de rechercher les mises à jour disponibles (pour les différentes versions de la plate-forme MS Windows) à partir de Microsoft Update.
Cela ne forcera pas l'installation.
Pour vérifier les mises à jour, allez dans Panneau de configuration, Sécurité, Windows Update, puis cliquez sur "Rechercher les mises à jour".
Une autre façon de forcer une véritable analyse des mises à jour consiste à effacer l'ardoise en supprimant toutes les mises à jour stockées dans% windir%\Windows\SoftwareDistribution\Download :
NET STOP wuauserv
RD /S /Q %windir%\SoftwareDistribution\Download
NET START wuauserv
Ensuite, allez dans Windows Update et "Vérifier les mises à jour". Cela peut prendre une heure, car chaque fichier pouvant être mis à jour sur votre volume système est vérifié (les "vérifications ultérieures des mises à jour" seront rapides). Cette approche élimine les erreurs, les mises à jour bâclées et donne un système propre et à jour, du moins dans la mesure où MS le voit.
j'utilise un outil tiers appelé wuinstall pour mettre à jour une nouvelle installation de Windows. avec cela, vous pouvez automatiser tout le processus de mise à jour, y compris les redémarrages automatiques. Je pense que c'est l'un des moyens les plus rapides de mettre à jour de nouvelles fenêtres sans la présence d'utilisateurs.
J'ai constaté que si, dans le cadre de votre nouvelle installation de Windows 7, vous mettiez à niveau IE ou que vous n'aviez pas encore exécuté IE et répondiez aux questions d'introduction, Windows Update vous donner une erreur. Je n'ai pas non plus trouvé le moyen de passer de Windows Update à Microsoft Update sans passer par l'interface graphique. J'ai donc lancé manuellement IE, l'initialisé puis installé Windows Update via l'interface graphique. Je peux donc basculer sur Microsoft Update et éviter les erreur initiale. Votre kilométrage peut varier.