web-dev-qa-db-fra.com

xsl: comment diviser des chaînes?

Je souhaite diviser une adresse sur des points-virgules (;) En lignes séparées par <br />:

par exemple. si address = 123 Elm Street, je veux sortir 123 Elm Street,

mais si address = 123 Elm Street;PO Box 222, je veux sortir

123 Elm Street<br />PO Box 222

et si address = 123 Elm Street;PO Box 222;c/o James Jones, je veux sortir

123 Elm Street<br />PO Box 222<br />c/o James Jones

Y a-t-il un moyen de faire cela? (probablement facile mais je ne connais pas très bien le XSLT)

Le sélecteur XSL ordinaire est

<xsl:value-of select="address"/>

et je voudrais modifier ce fragment XSLT pour le diviser en point-virgule.


mise à jour: Apparemment, la réponse implique l'utilisation de <xsl:call-template> et des fonctions substring-before() et substring-after().

Mais je suis un débutant en XSLT et je pourrais vraiment utiliser de l'aide pour le faire.

32
Jason S

I. Solution XSLT 1.0 simple:

Cette transformation :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="text()" name="split">
  <xsl:param name="pText" select="."/>
  <xsl:if test="string-length($pText)">
   <xsl:if test="not($pText=.)">
    <br />
   </xsl:if>
   <xsl:value-of select=
    "substring-before(concat($pText,';'),';')"/>
   <xsl:call-template name="split">
    <xsl:with-param name="pText" select=
     "substring-after($pText, ';')"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

lorsqu'il est appliqué sur ce document XML :

<t>123 Elm Street;PO Box 222;c/o James Jones</t>

produit le résultat corrigé souhaité :

123 Elm Street<br />PO Box 222<br />c/o James Jones

II. FXSL 1 (pour XSLT 1.0):

Ici, nous utilisons simplement le modèle FXSL str-map (et ne pas avoir à écrire de modèle récursif pour la 999e fois):

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/"
xmlns:testmap="testmap"
exclude-result-prefixes="xsl f testmap"
>
   <xsl:import href="str-dvc-map.xsl"/>

   <testmap:testmap/>

   <xsl:output omit-xml-declaration="yes" indent="yes"/>

   <xsl:template match="/">
     <xsl:variable name="vTestMap" select="document('')/*/testmap:*[1]"/>
     <xsl:call-template name="str-map">
       <xsl:with-param name="pFun" select="$vTestMap"/>
       <xsl:with-param name="pStr" select=
       "'123 Elm Street;PO Box 222;c/o James Jones'"/>
     </xsl:call-template>
   </xsl:template>

    <xsl:template name="replace" mode="f:FXSL"
         match="*[namespace-uri() = 'testmap']">
      <xsl:param name="arg1"/>

      <xsl:choose>
       <xsl:when test="not($arg1=';')">
        <xsl:value-of select="$arg1"/>
       </xsl:when>
       <xsl:otherwise><br /></xsl:otherwise>
      </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

lorsque cette transformation est appliquée sur un document XML (non utilisé), le même résultat correct souhaité est produit :

123 Elm Street<br/>PO Box 222<br/>c/o James Jones

III. Utilisation de XSLT 2.0

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="text()">
  <xsl:for-each select="tokenize(.,';')">
   <xsl:sequence select="."/>
   <xsl:if test="not(position() eq last())"><br /></xsl:if>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

lorsque cette transformation est appliquée sur ce document XML :

<t>123 Elm Street;PO Box 222;c/o James Jones</t>

le résultat voulu et correct est produit :

123 Elm Street<br />PO Box 222<br />c/o James Jones
63
Dimitre Novatchev

Si votre processeur XSLT prend en charge EXSLT , vous pouvez utiliser str: tokenize , sinon, le lien contient une implémentation utilisant des fonctions comme substring- avant.

2
Mormegil