web-dev-qa-db-fra.com

Comment utiliser XSLT pour créer des valeurs distinctes

J'ai XML comme ceci:

<items>
  <item>
    <products>
      <product>laptop</product>
      <product>charger</product>
    </products>
  </item>
  <item>
    <products>
      <product>laptop</product>
      <product>headphones</product>  
    </products>  
  </item>
</items>

Je veux qu'il sorte comme

 ordinateur portable 
 chargeur 
 casque

J'essayais d'utiliser distinct-values() mais je suppose que je fais quelque chose de mal. Quelqu'un peut-il me dire comment y parvenir en utilisant distinct-values()? Merci.

<xsl:template match="/">            
  <xsl:for-each select="//products/product/text()">
    <li>
      <xsl:value-of select="distinct-values(.)"/>
    </li>               
  </xsl:for-each>
</xsl:template>

mais ça me donne une sortie comme celle-ci:

<li>laptop</li>
<li>charger</li>
<li>laptop></li>
<li>headphones</li>
xslt
52
AB.

Une solution XSLT 1. qui utilise key et la fonction generate-id() pour obtenir des valeurs distinctes:

<?xml version="1.0" encoding="UTF-8"?>
  <xsl:stylesheet
   version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" encoding="UTF-8" indent="yes"/>

<xsl:key name="product" match="/items/item/products/product/text()" use="." />

<xsl:template match="/">

  <xsl:for-each select="/items/item/products/product/text()[generate-id()
                                       = generate-id(key('product',.)[1])]">
    <li>
      <xsl:value-of select="."/>
    </li>
  </xsl:for-each>

</xsl:template>

</xsl:stylesheet>
51
Mads Hansen

Voici une solution XSLT 1. que j'ai utilisée dans le passé, je pense qu'elle est plus succincte (et lisible) que d'utiliser la fonction generate-id().

  <xsl:template match="/">           
    <ul> 
      <xsl:for-each select="//products/product[not(.=preceding::*)]">
        <li>
          <xsl:value-of select="."/>
        </li>   
      </xsl:for-each>            
    </ul>
  </xsl:template>

Résultats:

<ul xmlns="http://www.w3.org/1999/xhtml">
  <li>laptop</li>
  <li>charger</li>
  <li>headphones</li>
</ul>
48
Nick Grealy

Vous ne voulez pas "sortie (valeurs distinctes)", mais plutôt "pour chaque (valeurs distinctes)":

<xsl:template match="/">              
  <xsl:for-each select="distinct-values(/items/item/products/product/text())">
    <li>
      <xsl:value-of select="."/>
    </li>
  </xsl:for-each>
</xsl:template>
18
Tomalak

Je suis arrivé à ce problème en travaillant avec un rendu Sitecore XSL. L'approche qui a utilisé la touche () et l'approche qui a utilisé l'axe précédent ont fonctionné très lentement. J'ai fini par utiliser une méthode similaire à key () mais qui ne nécessitait pas l'utilisation de key (). Il fonctionne très rapidement.

<xsl:variable name="prods" select="items/item/products/product" />
<xsl:for-each select="$prods">
  <xsl:if test="generate-id() = generate-id($prods[. = current()][1])">
    <xsl:value-of select="." />
    <br />
  </xsl:if>
</xsl:for-each>
14
Felix Steiny

distinct-values(//product/text())

8
Jim Garrison

J'ai trouvé que vous pouvez faire ce que vous voulez avec XSLT 1.0 sans les fonctions generate-id() et key().

Voici une solution spécifique à Microsoft (.NET's XslCompiledTransform class, ou MSXSLT.exe ou Microsoft platfocm COM-objects).

Il est basé sur cette réponse . Vous pouvez copier un ensemble de nœuds triés dans une variable ($sorted-products dans la feuille de style ci-dessous), puis convertissez-le en ensemble de nœuds à l'aide de ms:node-set une fonction. Vous pourrez alors for-each deuxième fois sur un ensemble de nœuds trié:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" xmlns:ms="urn:schemas-Microsoft-com:xslt" exclude-result-prefixes="ms">

  <xsl:output method="html" indent="yes" />

  <xsl:template match="/">
    <xsl:variable name="sorted-products">
        <xsl:for-each select="//products/product">
            <xsl:sort select="text()" />

            <xsl:copy-of select=".|@*" />
        </xsl:for-each>
    </xsl:variable>

    <xsl:variable name="products" select="ms:node-set($sorted-products)/product" />

    <xsl:for-each select="$products">
      <xsl:variable name='previous-position' select="position()-1" />

      <xsl:if test="normalize-space($products[$previous-position]) != normalize-space(./text())">
        <li>
          <xsl:value-of select="./text()" />
        </li>
      </xsl:if>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

sortie:

<li>charger</li>
<li>headphones</li>
<li>laptop</li>

Vous pouvez l'essayer dans la cour de récréation en ligne .

0
hal